Information Literacy: Use GNUPLOT

gnuplot を使う

今日の演習内容

関数のプロット
数値データのプロット
２次元プロット

関数のプロット

今週は大抵のＵＮＩＸシステムで利用できる、簡単なグラフ作成ツール gnuplot を使ってみる。

gnuplot の起動と簡単な使用

とにかく gnuplot を立ち上げる。 gnuplot は非ＧＵＩ環境から立ち上げるので、まず kterm を立ち上げ、kterm のウィンドウ内で「gnuplot」というコマンドを打つ。
```
   gnuplot
```
gnuplot が立ち上がり、少しメッセージが出た後に「gnuplot>」のプロンプトが出る。 gnuplot のコマンド待ちモードになったことがわかる。
では手始めに簡単な関数をプロットしてみる。関数をプロットするコンマンドは「plot」。以下のコマンドを試しに打ってみる。
```
   set title "My Simple Function 1"
   plot x
```
上の例では、プロットする絵のタイトルを「set title」というコマンドで設定している。後でどんな関数や数値をプロットさせたかがわかるように、タイトルを入れることを勧める。タイトルは２個の「"」で必ず囲まないと gnuplot が理解できないことに注意。この例でプロットした関数は「y=x」。 gnuplot の plot コマンドでは関数の引数（図の横軸）は「x」であるとみなされる。 plot コマンドを実行すると、新しくウィンドウが開き関数がプロットされたはず。関数をプロットする範囲（横軸の範囲）は gnuplot が適当に設定してくれたはず。
ではもう一つ別な関数をプロットしてみる。以下のようにコマンドを打つ。
```
    set title "My Simple Function 2"
    set xlabel "X-Axis"
    set ylabel "Y-Axis"
    plot x**2
```
この例では、Ｘ軸とＹ軸の名前を入れている。何のプロットかを理解するのに役立つように、座標軸にも名前を付けることを勧める。プロットした関数は「y=x**2（ｘの２乗）」。この様に gnuplot は大抵の関数をプロット出来る（cos(x), log(x), cos(x)+sin(x) など）。

プロットの仕方色々

今までの例では、一度に１個の関数しかプロットしなかったが、２個以上の関数を同時にプロットすることも出来る。以下の例を試してみる。
```
   set title "My Simple Functions 1 and 2"
   plot x,x**2
```
上の例のように２個以上の関数をカンマ「,」で区切って並べることで複数の関数を１つの図に納めることができる。
今までのプロットでは関数をプロットする範囲は gnuplot が勝手に決めていたが、今度は範囲を自分で決めてみる。以下のコマンドを試す。
```
   plot [0.0:2.0] x,x**2
```
プロットの範囲は [x1:x2] の様に指定してやると、ｘ１からｘ２の範囲がプロットされる。
いまＸ軸とＹ軸はともにリニアプロットになっているが、ログプロットが出来れば便利な場合がある。ログプロットの例としてセミログプロット（片対数プロット）を試してみる。
```
   set title "My Simple Function 3"
   plot [0.0:5.0] exp(-x)
   set title "My Semi-Log Plot"
   set logscale y
   plot [0.0:5.0] exp(-x)
   set nologscale y
```
最初の plot コマンドと二回目の plot コマンドの結果の違いがわかるだろうか。「set logscale」コマンドと「set nologscale」コマンドで、ログプロットにするかどうかどうかを変更する。
gnuplot にもパラメトリックプロットというのがある。以下のコマンドを試してみる。
```
   set parametric
   set title "My Parametric Plot"
   plot cos(t),sin(3*t)
   set noparametric
```
パラメットリックプロットというのはｘ座標とｙ座標が共通の変数（ここではｔ）の関数で与えられているいる時に都合の良いプロットだった。この例では「x=cos(t)」「y=sin(3*t)」となっている。 gnuplot が理解できる共通の変数は「t」だということに注意。最後の行のコマンドでパラメトリックプロットのモードを終了し、通常のプロットのモードに戻っている。

gnuplot の使い方がわかってきただろうか。 gnuplot の終了は「exit」あるいは「quit」コマンドで。

数値データのプロット

実験データなどをプロットしたい場合には、数値データファイルを用意し gnuplot にプロットさせるのが便利である。

数値データのプロット法

今度は関数のプロットではなくて、数値データのプロットをしてみる。用意したデータファイル gnuplot.dat を使用する（リンクを右クリックして保存）。
gEdit を起動し gnuplot.dat の中身を見てみる。見てわかるように、データファイルの中には、一行に３個データが書かれたものがズラーと並んでいる。３個のデータは各データのＸ座標、Ｙ座標、Ｙ座標の誤差を入れてある。
このデータを gnuplot でプロットしてみる。
```
   set title "My Simple Data Plot"
   set grid
   plot "gnuplot.dat"
```
このコマンドの例では、データファイル中のＸ座標とＹ座標のみを使ってプロットを行なった。プロットする前に実行している「set grid」コマンドは、プロット中にグリッドラインを入れるコマンド。ここではやらないが「set nogrid」で解除できる。データが入ったデータファイル名は２個の「"」で挟む必要がある。
次はＹ座標の誤差も入れてプロットしてみる。
```
   plot "gnuplot.dat" with errorbars
```
エラーバー（誤差棒）が各データポイントに付いたはず。
数値データと関数を同時にプロットすることもできる。
```
   plot "gnuplot.dat",0.25*x+9.0
   plot "gnuplot.dat" with errorbars,0.25*x+9.0
```
２番目の例では、エラーバー付きでデータをプロットした上に、関数をプロットしている。見てわかるように、数値データの方にエラーバーを付けるという意味で「"gnuplot.dat" with errorbars」をひとかたまりに書いている。

２次元プロット

gnuplot は２次元プロットももちろんできる。

簡単な２次元プロット

２次元のプロットを行なうコマンドは「splot」である。さっそく使ってみる。
```
   set title "My Simple 2D Plot"
   set xlabel "X-Axis"
   set ylabel "Y-Axis"
   set zlabel "Z-Axis"
   splot [-10:10] [-10:10] x**2-y**2
```
２次元プロットでは新たにＺ軸が付け加わるので、Ｚ軸の名前を付けている。プロットの範囲指定は２次元なのでＸとＹについて行なう必要がある。

プロットを見る角度を変えてみる。

   set view 80,30
   splot [-10:10] [-10:10] x**2-y**2
   set view 25,30
   splot [-10:10] [-10:10] x**2-y**2
   set view 60,60
   splot [-10:10] [-10:10] x**2-y**2

２次元プロットのタイプ色々

いまのプロットのタイプは surface だが、他のタイプに変更してみる。このタイプを contour（等高線）にしてみる。
```
   set nosurface
   set contour
   set view 0,0
   splot [-10:10] [-10:10] x**2-y**2
```
プロットが粗いためにあまり奇麗では無いが等高線が描けたはず。「set view 」コマンドは等高線が見易いように設定した。元の surface のタイプに戻すには以下のコマンドが使える。
```
   set nocontour
   set surface
```
１次元のプロットの所で出てきたパラメトリックプロットは、２次元のプロットでも使える。ただし違う点が２点ある。第１点は共通の変数（媒介変数と呼ばれる）が１個ではなくて２個あること。第２点は媒介変数の名前が「u」と「v」になっていること。１次元プロットではパラメトリックプロットは一本の線を描いたが、２次元では一本の線あるいは１枚の曲面を描く（通常は曲面だが媒介変数を一個しか用いないと線になる）。
一本の線になる例を一つ見てみる。
```
   set view 60,30
   set parametric
   splot cos(u),sin(u),u
```
一本の螺旋が描けたはず。

次に一枚の曲面になる例を見てみる。

   splot exp(-0.1*v)*cos(u),exp(-0.1*v)*sin(u),u

以上２次元のプロットの使い方だったが楽しめただろうか。