Information Literacy: Use Mathematica 2

Mathematica を使うその２

今日の演習内容

簡単なプロット
２次元プロット
３次元プロット

簡単なプロット

先週 Mathematica は「数値視覚化ソフトウェア」であるとも言った。今週は Mathematica のその辺の機能を見るために、色々なプロットコマンドを試してみる。まずは簡単なプロットから始める。

パラメトリック・プロット

とにかく Mathematica を立ち上げる。「メインメニュー」の「センターメニュー」「アプリケーション」「Mathematica 数式処理」をクリック。
簡単なプロットコマンドの例として ParametricPlot をみてみる。先週使った Plot コマンドでは、変数の値と１変数の関数の値を、それぞれ横軸と縦軸にプロットした。このように縦軸の値が簡単に１個の関数で書ける場合は良いが、横軸と縦軸を別々の関数で書いた方が簡単な場合もある。例えば下のような例。
```
   x = sin(ωt)
   y = cos(ωt)
```
この場合には横軸（x）も縦軸（y）も変数 t の関数となっている。このような場合には ParametricPlot を使ってやると、簡単にプロットできる。
ParametricPlot の書式と例は以下のようになる。
```
   ParametricPlot[ { 横軸の関数, 縦軸の関数 }, 変数とその変化範囲 ]
   ParametricPlot[ { Sin[t], Cos[t] }, {t,0,2Pi} ]
```
上の例で ParametricPlot を試すが、そのままでは余り面白味がないので Do コマンドも使い、以下のように入力し、最後にキーボードの space キーを押しながら enter キーを打つ（Mathematica の計算開始の方法を思い出すこと）。
```
   Do[
       ParametricPlot[
           { Sin[t], Cos[t+phi] }, 
           {t,0,2Pi},
           AspectRatio -> 1
       ],
       {phi,0,2Pi,Pi/20}
   ]
```
ParametricPlot コマンドには AspectRatio のオプションを付けた。このオプションを付けるとプロットの縦横比を与えることができる。 Do コマンドは変数 phi を変えながらプロットを繰り返す。プロットできた絵をアニメーションとして見てみる。プロットした絵の右側にある括弧のうち、左から２番目（複数のプロット全体を囲んでいる）をダブルクリックするとプロットが一つにまとまる。この状態で（プロットの横の矢印の付いた括弧を選択しているはず）、「Cell」プルダウンメニューの「Animate selected Graphics」をクリックするとアニメーション出来る。
上の例でできたプロットは、一般的にリサージュ図形と呼ばれる。例では横軸と縦軸の振動（三角関数）の振動数が同じだが（角速度はどちらも１）、一般的には振動数が違っても構わない。先の例を少し書き換えて、次の例を試してみる（書き換えた後に space キーを押しながら enter キーを打つ）。
```
   Do[
       ParametricPlot[
           { Sin[t], Cos[3t+phi] }, 
           {t,0,2Pi},
           AspectRatio -> 1
       ],
       {phi,0,2Pi,Pi/20}
   ]
```
少し複雑なプロットができたはず。これもやはりアニメーションとして見てみる。
振動数の比は必ずしも整数とする必要は無い。以下の例をやってみる。
```
   ParametricPlot[
       { Sin[t], Cos[1.02t] },
       {t,0,20Pi},
       AspectRatio -> 1
   ]
```
今回は t の変化範囲の上限が、２０πとなっているので注意。奇麗なプロットができたはず。

リスト・プロット

次は別なプロットのコマンドを使ってみる。今までのプロットの例では関数をプロットした。しかし一般的には横軸と縦軸の値が数値で与えられている場合もある。そのような場合には ListPlot コマンドが使える。

ListPlot コマンドの書式と例を下に示しす。

   ListPlot[ { {x1,y1}, {x2,y2}, ... {xn,yn} } ]
   ListPlot[ { {1,2}, {2,4}, {4,1} } ]

上の例を試してみる。表示を奇麗にするためにいくつかオプションを付ける。

   ListPlot[
       { {1,2}, {2,4}, {4,1} },
       PlotStyle -> PointSize[0.04],
       PlotRange -> { {0,5}, {0,5} }
   ]

指定した場所に点を打つことができただろうか。点を打つ代わりに線で結ぶこともできる。
```
   ListPlot[
       { {1,2}, {2,4}, {4,1} },
       PlotJoined -> True,
       PlotRange -> { {0,5}, {0,5} }
   ]
```
上の例ではプロットする点を全てリストアップしなければならない点が面倒。プロットする点をリストアップするのを手伝ってくれるコマンド Table がある。例として f(z)=1/(1+i(z-1/z)) という複素関数の、実数部分と虚数部分をプロットするとし、そのリストアップを Table コマンドでやってみる。

Table コマンド部分だけをまずやってみる。

   f[z_] := 1 / ( 1 + I(z-1/z) );
   Table[
       { Re[f[w]], Im[f[w]] },
       {w, 0.1, 5.0, 0.05}
   ]

この例ではまず関数 f(z) を定義している。関数定義中の「I」は虚数 i を示す。このように関数を自由に定義できる。定義中の等号は「：=」であることに注意。次に Table コマンドの中では {Re[f[w]], Im[f[w]]} という数値のペアを必要なだけ作っている。
変数 w は 0.1 から 5.0 まで 0.05 きざみで変化させている。 Re[ ] と Im[ ] は、それぞれ数値の実数部分と虚数部分を求めるコマンド。上の例でもわかるように Table コマンドの書式は
```
   Table[ 作りたいもの , 変数と変数の範囲及びステップサイズ ]
```
である。

後はこれを ListPlot を使ってプロットする。

   f[z_] := 1 / ( 1 + I(z-1/z) )
   ListPlot[
       Table[
           { Re[f[w]], Im[f[w]] },
           {w,0.1,5.0,0.05}
       ],
       AspectRatio -> 1,
       PlotStyle -> PointSize[0.04]
   ]

この例の ListPlot コマンドの中は、１つ前の例で数値として与えられていたプロットする点が、 Table コマンドで置き換わっている。参考までに言うと、この例でできるプロットは、物理的には抵抗とコイルとコンデンサーを直列につないだ回路に、正弦波を入れた時の共振特性と同等（R=L=C=1 とすれば上の式のようになる）。
ここでやった計算を、例えば math というディレクトリーの、 simpleplot.nb というファイルにセーブする（「File」プルダウンメニューの「Save」をクリック）。

２次元プロット

次は２次元プロットをいくつか試してみる。

デンシティー・プロット

新しいウィンドウを開く（「File」プルダウンメニューで「New」をクリック）。 DensityPlot というコマンドを使ってみる。 DensityPlot はその名の通り、２次元関数の値を density（濃さ）で表示する。
下の例を試してみる。
```
   DensityPlot[
       x^2 - y^2,
       {x,-1,1},
       {y,-1,1}
   ]
```
この例では x^2-y^2 という２次元の関数をプロットする。プロットする範囲は x と y それぞれについて指定できる。

DensityPlot の書式は以下の通り。

   DensityPlot[ プロットする関数 , 横軸の範囲 , 縦軸の範囲 ]

上の例では、絵が荒いのとグリッドライン（縦横に入っている直線）が邪魔。下のようにすると少し奇麗になるはず。
```
    DensityPlot[
        x^2 - y^2,
        {x,-1,1},
        {y,-1,1},
        PlotPoints -> 50,
        Mesh -> False
    ]
```
PlotPoints を大きくすれば、いくらでも細かいプロットができるが、計算時間が長くかかる。 Mesh は True にするとグリッドラインを描き、 False にすると描かない。

もちろんカラー表示もできる。

   DensityPlot[
       x^2 - y^2,
       {x,-1,1},
       {y,-1,1},
       PlotPoints -> 50,
       Mesh -> False,
       ColorFunction -> (Hue[#/2]&)
   ]

コントア・プロット

もう一つ別な２次元プロットをしてみる。使うコマンドは ContourPlot で、等高線を描くコマンドである。以下の例をやってみる。
```
   ContourPlot[
       x^2 - y^2,
       {x,-1,1},
       {y,-1,1}
   ]
```
関数は先ほどの例と同じ。またコマンドの書式もほぼ同じなので、オプションの意味もわかるはず。
今度の例では色の塗り分けが少し邪魔なので、取り払ってみる。
```
   ContourPlot[
       x^2 - y^2,
       {x,-1,1},
       {y,-1,1},
       ContourShading -> False
   ]
```
すっきりした等高線になったはず。
ここでやった例を 2dplot.nb というファイルにセーブする。

３次元プロット

次は３次元プロットをみてみる。

３次元プロットの例

３次元プロットするコマンドは Plot3D。新しいウィンドウを開き、２次元のときと同じ関数を３次元プロットしてみる。
```
   Plot3D[
       x^2 - y^2,
       {x,-1,1},
       {y,-1,1}
   ]
```

ではもう一つ例を見てみる。

   Plot3D[
       Sin[x+y],
       {x,-2Pi,2Pi},
       {y,-2Pi,2Pi}
   ]

余り解像度が良く無いのと、グリッドラインが少し邪魔。これを直すために下の例を試す。

   Plot3D[
       Sin[x+y],
       {x,-2Pi,2Pi},
       {y,-2Pi,2Pi},
       PlotPoints -> 30,
       Mesh -> False
   ]

上の例は Sin(x+y) を Sin(x+y-t) とすれば、先週やった進行波のアニメーションのときの関数と似て来る。３次元のアニメーションを以下の例のように作ってみる。
```
   Do[
       Plot3D[
           Sin[x+y-t],
           {x,-2Pi,2Pi},
           {y,-2Pi,2Pi},
           PlotPoints -> 30,
           Mesh -> False
       ],
       {t,0,2Pi,Pi/10}
   ]
```
アニメーションして波が進んで行く様子を３次元的に見れただろうか。

Plot3D コマンドには、３次元プロットを見る視点を変えるオプション ViewPoint もある。横から見たプロットの例２個と、真上から見たプロットの例１個を試してみる。

   Plot3D[
       Sin[x+y],
       {x,-2Pi,2Pi},
       {y,-2Pi,2Pi},
       PlotPoints -> 30,
       Mesh -> False,
       ViewPoint -> {1,1,0}
   ]
   Plot3D[
       Sin[x+y],
       {x,-2Pi,2Pi},
       {y,-2Pi,2Pi},
       PlotPoints -> 30,
       Mesh -> False,
       ViewPoint -> {1,-1,0}
   ]
   Plot3D[
       Sin[x+y],
       {x,-2Pi,2Pi},
       {y,-2Pi,2Pi},
       PlotPoints -> 30,
       Mesh -> False,
       ViewPoint -> {0,0,3}
   ]

当然 ViewPoint を変えたアニメーションも作れる。以下の例を試してみる。

   Do[
       Plot3D[
           Sin[x+y],
           {x,-2Pi,2Pi},
           {y,-2Pi,2Pi},
           PlotPoints -> 30,
           ViewPoint -> {2Cos[phi],2Sin[phi],1},
           SphericalRegion -> True,
           Axes -> None
       ],
       {phi,0,Pi,Pi/20}
   ]

上の例ではアニメーションが奇麗に見えるように SphericalRegion と Axes のオプションを使った。
ここでやった例を 3dplot.nb にセーブしておく。

Mathematica を使う その２

Mathematica を使うその２