Information Literacy: Use Spreadsheet 2

スプレッドシートを使うその２

今日の演習内容

微分（差分）
数値積分
スプレッドシートで力学？

微分（差分）

今週はスプレッドシートの本来の使い方とは少し違う使い方をしてみる。

数学では関数の微分を行なうことがあるが、これを数値計算で行なう作業を「差分をとる」という。微分の定義に立ち帰ると x の関数 f の微分は、

df/dx = lim_{dx -> 0} (f(x+dx)-f(x))/dx

である。数値計算では dx を本当にゼロまでは持っていけないので、有限の（ただし小さい）dx を使って微分を近似計算する。

今回はサイン関数 sin(x) の x による差分を例として計算してみる。

準備

スプレッドシートの計算機能を使って、サイン関数 sin(x) の x による差分計算をしてみる。
まず Applix スプレッドシートを起動する。「メインメニュー」の「センターメニュー」「アプリケーション」「Applixware オフィススイート」「Applix スプレッドシート」をクリック。
シート中のセルＡ１からＥ１に「x」「sin(x)」「diff」「diff/dx」「cos(x)」と書き込む。従って、これから列Ａに変数 x の値、列Ｂに sin(x) の値（差分をとるべき関数値）、列Ｃに sin(x+dx)-sin(x) の値、列Ｄに差分の値（つまり (sin(x+dx)-sin(x))/dx の値）、列Ｅに差分と比較するために sin(x) の微分値（つまり cos(x) の値）をそれぞれ入力して行く。
またセルＧ１に「dx」と書き込み、セルＧ２に数値 0.1 を入力する。従って、dx の値として 0.1 を使うことにする。後に説明するが、この数値 0.1 はいつでも変更可能で、差分や微分の計算に反映できる。

変数 x の数値入力

セルＡ２に数値 0 を入力する。これが変数 x の最小値になる。
セルＡ３に以下のように入力する。
```
   =A2+$G$2
```
この式は、基本的にはセルＡ２（x の最小値）とＧ２（dx の値）を足しなさいという計算だが、「G2」が「$G$2」となっている。この「$」の意味については次に述べる。
セルＡ３の内容を、他の列Ａのセルにコピーする。まずセルＡ３を選択し（セルＡ３をクリック）、「編集」プルダウンメニューの「コピー」をクリック。次にセルＡ４からＡ７０を選択。セルＡ４でマウスボタンを押し、ポインターをＡ７０まで移動した後にマウスボタンを離しても良いが、マウスの動きに対して画面スクロールが速く動き過ぎるので、最初にＡ７０でマウスボタンを押し、Ａ４まで移動する方がセル選択がし易い。「編集」プルダウンメニューの「貼り付け」をクリック。この操作で、dx ずつ（0.1 ずつ）増加する数値が列Ａに入ったはず。これと同等のことを手で入力するのは大変なことは予想できるはず。
ここでコピーされたセルＡ４の数式を見てみる（セルＡ４をクリック）。内容は以下のようになっているはず。
```
   =A3+$G$2
```
前回の演習内容で、セルのデータを別のセルにコピーしたときには、今回のようにセルＡ４がコピー元のセルＡ３から見て、位置が縦に１行ずれている場合は、
```
   =A3+G3
```
となるはずであるが、「$G$2」は「$G$3」とは変わらずに元のままである。今回の作業では、常に 0.1 というセルＧ２の値だけ増加させたいので、これで良いのである。もし $G$3 となってしまうとセルＧ３は空白なので 0 が足されてしまう（従って x が増加してくれない）。
予想が付くと思うが「$」は、セルの数式を他のセルにコピーした際に、セルの列や行を変更しないようにするための指定法である。「$」は列と行それぞれに付けたり付けなかったり出来る。例えばセルの列は変更せず行は自動変更する場合には「$G2」のように、セルの列は自動変更し行は変更しない場合には「G$2」のようにも指定できる。今回の場合はＡ３のセルを以下のようにしても結果は同じである。
```
   =A2+G$2
```

関数 sin(x) の用意

変数 x が用意できたので、関数 sin(x) を計算するのは簡単である。まずＢ２に以下のように入力する。
```
   =sin(A2)
```
サイン関数はスプレッドシートの関数として用意されている。Ａ２のセルには x の値が入っているのでセルＢ２には、その x の値に対応して sin(x) の値が入ることになる。
あとは単純にセルＢ２の数式を、セルＢ３からＢ７０までコピーすれば良い。

差と差分の計算

差 sin(x+dx)-sin(x) の計算は簡単である。セルＣ２に以下のように入力する。
```
   =B3-B2
```
あとはセルＣ２の数式を、セルＣ３からＣ６９までコピーすれば良い。ここで、セルの最後がＣ６９になっているのは、もしセルＣ７０にもコピーを行なった場合セルの数式が
```
   =B71-B70
```
となってしまうためである。Ｂ７１は定義されていないので（計算上は 0 と見なされる）変な結果になってしまう。
同様に差分の計算は、まずセルＤ２に以下のように入力する。
```
   =C2/$G$2
```
ここでも dx の値が入っているセルＧ２は変化させたくないので、「$」を付けている。あとはセルＤ２の数式を、セルＤ３からＤ６９までコピーすれば良い。先にも言ったように、上の数式は
```
   =C2/G$2
```
としても結果は同じである。
差の計算と差分の計算を一緒にするのであれば以下の数式を用いても良い。
```
   =(B3-B2)/$G$2
```
この場合には列Ｃの設定は必要無くなる。

関数 cos(x) の用意

差分の結果と比較するために関数 cos(x) を計算する。やりかたは sin(x) の場合と同様で、まずＥ２に以下のように入力する。
```
   =cos(A2)
```
コサイン関数はスプレッドシートの関数として用意されている。
あとはセルＥ２の数式を、セルＥ３からＥ６９までコピーすれば良い。

差分と微分の比較

これまでの入力と操作で、サイン関数の差分（列Ｄ）とサイン関数の微分（コサイン関数、列Ｅ）が計算できているので、数値的には比較可能である。これを視覚的に見るためにグラフを描くことにする。
まずセルの領域Ａ２からＡ６９を選ぶ。これがグラフのＸ軸になる。行１を選ぶとうまくグラフにならないので行１は避けた（バグ？）。
更にＹ軸の値としてサインの差分と微分を選ぶ。先ほどのセルの領域に追加したいので、キーボードの CTRL キーを押しながら、セルの領域Ｄ２からＥ６９を選ぶ。
この状態で、グラフのボタン（「棒グラフ」のアイコン）をクリック。ポインターが小さな棒グラフとなるので、シートの適当な場所でマウスボタンを押し、そのままポインターを適当な量だけ移動する。長方形の領域が表示され、それがグラフの描画領域となる。
後はグラフ描画のウィザードに従ってグラフ描画の条件を決めて行く。今回のグラフは、「散布図」のグラフとし（中段左から３番目）、点と点をつなぐように指定すること（下段左から２番目）。
差分計算は結構精度が良いことが分かるはず。違いを見るには図を横長に引き延ばすのが良い。シートの dx の値を変化させると、シート中の差分値計算の結果が変化し、またグラフの内容も変化する。 dx の値により計算精度が変わる様子を見ると良い。
なお間違って作ったグラフを消すには、「編集」プルダウンメニューの「削除」「オブジェクト」で「グラフ」を削除する。

以上の操作で出来たシートを前回作った spred というディレクトリーに、 Applix スプレッドシート固有の形式で保存する。「ファイル」プルダウンメニューの「上書き保存」をクリック。ファイル名を付けて保存。

ここでは差分される関数としてサイン関数を用いたが、一般的には差分されるものは数値データでも良い。また変数 x の間隔も今回は一定であったが、一般には非等間隔の x について与えられた数値データの差分が計算できる。

数値積分

今度はスプレッドシートの計算機能を使って、差分の逆操作である数値積分をやってみる。

まず積分の定義を思い出すことにする。積分区間を dx の長さで N 等分した場合の各分割点での関数 f の値を f_N と書くと、関数 f の x に関する積分は以下のように定義できる。

lim_{dx -> 0}( f₀dx + f₁dx + ... + f_Ndx )

数値積分では dx を無限小には持っていけないので、ある有限の（ただし小さい） dx で数値計算を行なう。

今回積分する関数は 1/x とし、不定積分を計算する。積分区間の下限は x=1 とする。

準備

「ファイル」プルダウンメニューの「新規作成」で新しいシートを用意する。
セルＡ１からＥ１に「x」「1/x」「(1/x)dx」「sum of (1/x)dx」「log(x)」と書き込む。従って、列Ａが変数 x の値、列Ｂが積分すべき関数 1/x の値、列Ｃが被積分関数と微小な変数 x の区間 dx の積、列Ｄが数値積分の結果、列Ｅが比較のための関数 log_e(x) の値というように計算してゆく。
セルＧ１に dx と書き込み、その値 0.1 をセルＧ２に書き込む。
先ほどと同じやりかたで x の準備をする。セルＡ２に x の初期値 1 を入力。セルＡ３には以下の数式を書き込む。
```
   =A2+$G$2
```
更にセルＡ３の数式を、セルＡ４からＡ７０までコピー。これで変数 x の用意が出来たはず。

被積分関数の用意から数値積分まで

次に被積分関数 1/x の値を用意する。セルＢ２に以下の数式を入れる。
```
   =1/A2
```
更にセルＢ２の数式を、セルＢ３からＢ７０までコピーする。
被積分関数と dx の積を計算する。セルＣ２に以下の数式を書き込む。
```
   =B2*$G$2
```
またセルＣ２の内容を、セルＣ３からＣ７０までコピーする。
数値積分は列Ｃの数値を順次足して行けば良い。まず積分区間の下限では積分値がゼロなので、セルＤ２に 0 を代入。セルＤ３には以下の数式を代入。
```
   =D2+C2
```
後はセルＤ３の数式を、セルＤ４からＤ７０までコピー。この操作で列Ｃの和が順次とれることは、良く考えれば分かるはず。
もちろんセルＣの計算とセルＤの計算は、
```
   =D2+B2*$G$2
```
と書けば列Ｃは省略できる。ここでは、計算の手順が分かり易いように列Ｃを一旦入れている。

関数 log_e(x) の用意

数値積分の結果と比較するために関数 log_e(x) を計算する。Ｅ２に以下のように入力する。
```
   =ln(A2)
```
自然対数 e を底とするログ関数は、スプレッドシートの関数として用意されている。関数の名前が ln（log natural の意味）である点に注意。
あとはセルＥ２の数式を、セルＥ３からＥ７０までコピーすれば良い。

数値積分と解析的な積分の比較

1/x の数値積分（列Ｄ）と解析的な積分結果である log_e(x) （列Ｅ）の違いを視覚的に見るためにグラフを描く。
セルの領域Ａ２からＡ７０を選ぶ
更にキーボードの CTRL キーを押しながら、セルの領域Ｄ２からＥ７０を選ぶ。
この状態で、グラフのボタン（「棒グラフ」のアイコン）をクリック。ポインターが小さな棒グラフとなるので、シートの適当な場所でマウスボタンを押し、そのままポインターを適当な量だけ移動する。
後はグラフ描画のウィザードに従ってグラフ描画の条件を決めて行く。今回のグラフも、「散布図」のグラフとし、点と点をつなぐように指定すること。
数値積分は結構精度が良いことが分かるはず。シートの dx の値を変化させると、シート中の差分値計算の結果が変化し、またグラフの内容も変化する。 dx の値により計算精度が変わる様子を見ると良い。

以上の操作で作ったシートを、Applix スプレッドシートの固有形式で保存する。

スプレッドシートで力学？

これまでやったことの応用として、スプレッドシートの計算機能を使い、力学で出て来るようなニュートンの運動方程式の、数値解を求めることにする。扱う運動方程式は最も簡単なバネの振動の運動方程式とする。運動方程式は、例えば、

m d²x/dt² = - kx

のように書けるが、簡単のために m=k=1 としてしまう。従って扱う微分方程式は、

d²x/dt² = - x

となる。

準備

「ファイル」プルダウンメニューの「新規作成」で新しいシートを用意する。
まずセルＡ１からＥ１に、「t」「x」「v」「a」「sin(t)」と書く。従って、列Ａには時刻 t の値（今回は位置 x が時間 t の関数であることに注意）、列Ｂには位置 x の値（これが運動方程式の解）、列Ｃには速度 v の値、列Ｄには加速度 a の値、列Ｅには比較のために運動方程式の特解の一つである sin(t) の値を書き込むことになる。
更にセルＧ１に dt と書き込み（微小な時間）、その値 0.1 をセルＧ２に書き込む。
時刻 t の値を入力する。時刻の初期値をゼロとするので、セルＡ２に 0 を記入。セルＡ３には以下の数式を書き込む。
```
   =A2+$G$2
```
後はセルＡ３の数式を、セルＡ４からＡ７０までコピーすれば、時刻 t の値が用意できる。

位置、速度、加速度の計算

まず位置 x と速度 v の初期値を設定する。セルＢ２とＣ２にそれぞれ、 0 と 1 を入力する。これにより、時刻 t=0 の位置が x=0 速度が v=1 と設定されたことになる（運動方程式の特解を決めるには２つの条件が必要）。
次に運動方程式を使うと加速度 a が計算できる。セルＤ２に以下のように書き込む。
```
   =-B2
```
加速度 a が与えられると速度 v が計算できる。加速度と速度の関係は、
```
   dv/dt = a
```
であり、これを書き直すと、
```
   dv = a dt
```
となり、これが時間 dt の間の速度 v の変化量となる。これを考慮すると、セルＣ３には以下のような数式を代入すれば良い。
```
   =C2+D2*$G$2
```
位置 x に付いても同様の考察を行なうと、セルＢ３に入れる式は以下のようになる。
```
   =B2+C3*$G$2
```
ここで、速度の計算のときと違って、速度の行３の値（C3）を使っているが、この方が数値計算結果の精度が良いのでこうした（余り気にしないように）。
最後にセルＤ２の数式を、セルＤ３にコピーすれば、列ＢからＤまでの３行目が全てそろったことになる。
セルＢ３からＤ３までをそれ以外の行にまとめてコピーする。まずセルＢ３からＤ３までを選択する（セルＢ３でマウスボタンを押し、ポインターをＤ３まで移動しマウスボタンを離す）。この状態で「編集」プルダウンメニューの「コピー」をクリック。次にセルＢ４からＤ７０を選択（３列を一気に選択している点に注意）。この状態で「編集」プルダウンメニューの「貼り付け」をクリック。このように、１つのセルだけでなく複数のセルを一気にコピーすることもできる（ただしあまり変なセルの選択をしない限り）。

特解 sin(x) の計算とグラフ化

セルＥ２に以下のように入力。
```
   =sin(A2)
```
後はセルＥ２の数式を、セルＥ３からＥ７０までコピーする。
時刻 t（列Ａ）、数値計算による位置 x（列Ｂ）、解析的に解いた場合の特解 sin(x)（列Ｅ）をグラフにしてみる。ここでも「散布図」のグラフが見易い。
数値計算による微分方程式の解は結構精度が良いことが分かるはず（dt が 0.1 の場合にはほとんど区別が付かない）。時間の区切りの大きさ dt を変化させると計算精度が変わるのが見れるはず。

以上の操作で出来たシートを Applix スプレッドシートの固有形式で保存する。

スプレッドシートを使う その２

スプレッドシートを使うその２